#!/usr/local/bin/perl 

=head1 NAME

updatedb.pl - a script for creation of new database. 

=head1 SYNOPSIS

updatedb.pl B<[-i]> I<file1> I<file2>....


=head1 DESCRIPTION

Updates information in the B<chgk> databse. Uses file

=head1 OPTIONS

=item B<-i> 

Ask about ParentId. 


=head1 BUGS

The database, user and password are hardcoded. 

=head1 AUTHOR

Dmitry Rubinstein

=head1 $Id: updatedb.pl,v 1.39 2004/01/11 00:14:32 boris Exp $

=cut

use vars qw($opt_i);

use Getopt::Std;
my $unsortedname="../dump/unsorted";
getopts('i');
#open STDERR, ">errors";
my $Interactive=$opt_i || 0;
my $DUMPDIR = $ENV{DUMPDIR} || "../dump";

my (%RevMonths) = 
    ('Jan', '1', 'Feb', '2', 'Mar', '3', 'Apr', '4', 'May', '5', 'Jun', '6',
     'Jul', '7', 'Aug', '8', 'Sep', '9', 'Oct', '10', 'Nov', '11',
     'Dec', '12', 
     'JAN', '1', 'FEB', '2', 'MAR', '3', 'APR', '4', 'MAY', '5', 'JUN', '6',
     'JUL', '7', 'AUG', '8', 'SEP', '9', 'OCT', '10', 'NOV', '11',
     'DEC', '12', 
     'Янв', '1', 'Фев', '2', 'Мар', '3', 'Апр', '4', 'Май', '5',
     'Июн', '6', 'Июл', '7', 'Авг', '8', 'Сен', '9', 
     'Окт', '10', 'Ноя', '11', 'Дек', '12');
my ($sth);





use DBI;
use strict;
my $isunsorted=0;
sub UpdateParents {
    my ($dbh, $ParentId, $all_qnum,$CreatedAt) = @_;
    if ($ParentId) {
	my ($sth1) = $dbh->prepare("SELECT QuestionsNum, ParentId, CreatedAt
FROM Tournaments WHERE Id = $ParentId");
	$sth1->execute;
	my ($q, $p,$c) = ($sth1->fetchrow)[0, 1, 2];
	$c=$CreatedAt if $CreatedAt && ($CreatedAt gt $c);
	my $qc=$dbh->quote($c);
	$dbh->do("UPDATE Tournaments SET 
                  QuestionsNum=$q + $all_qnum, CreatedAt=$qc
                  WHERE Id = $ParentId");
	&UpdateParents($dbh, $p, $all_qnum,$c);
    }
}


sub getField {
    my($desc, $dbh) = @_;
    my($key);
    my($value) = ('');
    while (<$desc>) {
	s/[]//g;
	if ($key && /^\s*$/) {
	    chomp $value;
            $value =~ s/\s+$//;
	    chomp $key;
	    if ($key eq 'Дата') {
		$value =~ s/^(.*)-(.*)-(.*)$/$3-$2-$1/;
		my($month) = $RevMonths{$2} || '01';
		$value =~ s/-(.*)-/-$month-/;
		$value =~ s/-00*$/-01/;
	    }
	    if ($key eq 'Автор') {$value=~s/\.$//;}
	    $value = $dbh->quote($value);
	    return ($key, $value);
	}
	next if (/^\s*$/);
	
	if (!$key && /^(.*?)[:\.]\s*(.*)$/s) {
	    $key = $1;
	    $value=$2;
	    next;
	}
	if ($key) {
	    $value .= $_;
	    next;
	}
    }
    if ($key && $value) {
        $value=~s/\s+$//;
	$value = $dbh->quote($value);
	return ($key, $value);
    }
    return (0, 0);
}

sub SelectGroup {
    my ($dbh, $source, $TourName) = @_;
    my ($sth, $ParentId, $i, @arr);

    if ($Interactive) {    
    	$sth = $dbh->prepare("SELECT Id, Title FROM
		Tournaments WHERE Type = 'Г'");
    	$sth->execute;
    	print "Выберите группу для турнира:\n$TourName, файл $source\n\n";
    	while (@arr=$sth->fetchrow) {
		print "[$arr[0]] $arr[1]\n";
    	}
    	$ParentId = <STDIN>;
    	chomp $ParentId;
    	if (!$ParentId) {
		print "Пропускаем файл $source\n";
		print STDERR "Файл $source отвергнут оператором\n";
		return (0,0);
    	} else {
		print "Вы выбрали турнир: $ParentId\n";
		$sth = $dbh->prepare("INSERT INTO Tournaments
			      (Title, Type, ParentId, FileName) 
			       VALUES ($TourName, 'Ч', $ParentId, 
                                       $source)");
		$sth->execute;
		my $TournamentId = $sth->{mysql_insertid};
		return ($TournamentId,$ParentId);
	}
    } else {
# Теперь, если файла нет в дереве турниров, никаких вопросов не 
# задаётся, а вместо этого он добавляется в группу 9999
		$ParentId = 9999;
		my $tempsource=$source;
		my $temptname=$TourName;
                $tempsource=~s/^\'(.*)\'$/$1/;
                $temptname=~s/^\'(.*)\'$/$1/;
	   	print UNSORTED "$tempsource".((12 -length($source))x' ')."\t$temptname\n";
		$isunsorted=1;
		$sth = $dbh->prepare("INSERT INTO Tournaments
			      (Title, Type, ParentId, FileName) 
			       VALUES ($TourName, 'Ч', $ParentId, 
                                       $source)");
                $sth->execute;
		my $TournamentId = $sth->{mysql_insertid};
		return ($TournamentId,$ParentId);
	}
		
    
}

sub UpdateTournament {
    my ($dbh, $TournamentId, $field, $value) = @_;
    $dbh->do("UPDATE Tournaments SET $field=$value WHERE Id=$TournamentId")
	or die $dbh->errstr;
}

sub UpdateQuestion {
    my ($dbh, $QuestionId, $field, $value) = @_;
    $dbh->do("UPDATE Questions SET $field=$value 
		WHERE QuestionId=$QuestionId")
	or die $dbh->errstr;
}

sub CheckFile {
    my ($dbh, $source, $title) = @_;
    my $sth = $dbh->prepare("SELECT Id,ParentId,QuestionsNum FROM Tournaments
                             WHERE FileName=$source AND Type='Ч'");
    $sth->execute or die $dbh->errstr;
    my @arr = $sth->fetchrow;
    if (! scalar @arr) {
	return SelectGroup($dbh,$source,$title);
    }
    my($Id,$ParentId,$QuestionsNum)=@arr;
    if($QuestionsNum) {	
	print "Файл $source с данными $title уже существует. ",
	"Заменить?[y/N]\n";
	my $answer = <STDIN>;
	if ($answer !~ /^[yY]/) {
	    return (0,0);
	} else {
	    DeleteTournament($dbh,$Id,$ParentId,$QuestionsNum,0);
	}
    } 
    return($Id,$ParentId);	
}


sub DeleteTournament {
    my ($dbh,$Id,$ParentId,$QuestionsNum,$DeleteMyself) = @_;
    if ($QuestionsNum) {
	UpdateParents($dbh,$ParentId,-$QuestionsNum);
    }
    my (@Tours) = &GetTours($dbh, $Id);
    foreach my $Tour (@Tours) {
	DeleteTournament($dbh,$Tour,$Id,0,1);
    }
    my $sth = $dbh->prepare("DELETE FROM Questions
                             WHERE ParentId=$Id");
    $sth->execute or die $dbh->errstr;
    if($DeleteMyself) {
	$sth = $dbh->prepare("DELETE FROM Tournaments
                             WHERE Id=$Id");
	$sth->execute or die $dbh->errstr;
    }
}

sub GetTours {
	my ($dbh, $ParentId) = @_;
	my (@arr, @Tours);

	my ($sth) = $dbh->prepare("SELECT Id FROM Tournaments
		WHERE ParentId=$ParentId ORDER BY Id");

	$sth->execute;

	while (@arr = $sth->fetchrow) {
		push @Tours, $arr[0];
	}

	return @Tours;
}

sub CreateTour {
    my ($dbh,$title,$ParentId,$TourNum,$rh_defaults)=@_;
    my $sth = $dbh->prepare("INSERT INTO Tournaments
			     (Title, Type, ParentId, Number) 
			     VALUES ($title, 'Т', $ParentId, $TourNum)");
    $sth->execute;
    my $TourId = $sth->{mysql_insertid};
    while (my ($key,$value)=each %$rh_defaults) {
	&UpdateTournament($dbh, $TourId, $key, $value);
    }
    return $TourId;
}
		

MAIN: 
{
    my($key, $value, $addition);
    #
    # Inherited fields for a Tour or Tournament
    #
    my %TourFields = ('Копирайт' => 'Copyright',
		      'Инфо' => 'Info', 'URL' => 'URL',
		      'Ссылка' => 'URL', 'Редактор' => 'Editors',
		      'Обработан'=> 'EnteredBy',
		      'Дата'=>'PlayedAt');
    #
    # Inherited fields for a Question
    #
    my %QuestionFields = ('Тип'=> 'Type', 'Вид'=> 'Type', 
			  'Автор' => 'Authors', 'Рейтинг'=>'Rating', 
			  'Источник' => 'Sources',
			  'Тема' => 'Topic');
			  
		      
    my($source);
    
    my($dbh) = DBI->connect("DBI:mysql:chgk", "piataev", "")
	or die "Can't connect to DB chgk\n";
    my @sources;	
    open UNSORTED, ">$unsortedname";
    while ($source = shift) {
       push @sources,glob($source);
    }
    foreach $source(@sources) {
	my $TourNum=0;
	my($PlayedAt) = '';
	my($QuestionId, $TourId, $TournamentId, $ParentId) = (0, 0, 0, 0);
	my($tournum, $qnum, $all_qnum) = (0, 0, 0);
	my (@d) = (localtime((stat($source))[9]))[5,4,3];
	$d[1]++;
	$d[1]=sprintf("%02d",$d[1]);
	$d[2]=sprintf("%02d",$d[2]);
	$d[0]+=1900;
	my $UnquotedCreated=join('-', @d);
	my ($CreatedAt) = $dbh->quote($UnquotedCreated);

	open INFD, $source 
	    or die "Can't open input file: $!\n";
	
	$source =~ s/^.*\/([^\/]*)$/$1/;
	my $unquotedsource=$source;
	$unquotedsource=~s/\.txt\s*$//;
	$source = $dbh->quote($source);
	print STDERR "Файл: $source, дата: $CreatedAt ";
	my %TourDefaults=('CreatedAt'=>$CreatedAt);
	my %QuestionDefaults=();
	my %QuestionGlobalDefaults=('Type'=>$dbh->quote('Ч'));
	while (($key, $value) = getField(\*INFD, $dbh)) {
	    last if (!$key);
	    
	    if ($key =~ /Мета/) {
		next;   # This is obsolete
	    }
	    if ($key =~ /Чемпионат/ || $key =~ /Пакет/) {		
		($TournamentId, $ParentId) = CheckFile($dbh,$source,$value);
		if (!$TournamentId)  {
		    last;
		}	
		$sth = $dbh->prepare("UPDATE Tournaments SET
			             Title=$value, Type='Ч', 
                                     ParentId=$ParentId, 
                                     FileName=$source, 
                                     CreatedAt=$CreatedAt
                                     WHERE
                                     Id=$TournamentId");
		$sth->execute;
		next;
	    }
	    if ($key =~ /Тур/) {
		if ($TourId) {

	    		$dbh->do("UPDATE Tournaments SET QuestionsNum=$qnum
			      WHERE Id=$TourId");
		}
		$qnum = 0;
		$TourNum++;
		$TourDefaults{'FileName'}=$dbh->quote(
                        			"$unquotedsource.$TourNum"
						);
		$TourId=CreateTour($dbh,$value,$TournamentId,$TourNum,
				   \%TourDefaults);
		%QuestionDefaults=%QuestionGlobalDefaults;
		$QuestionId=0;
		next;	
	    }
	    if ($key =~ /Вопрос/) {
		if (!$TourId) {
		    $qnum = 0;
		    $TourNum++;
		    $TourId=CreateTour($dbh,'1',$TournamentId,$TourNum,
				       \%TourDefaults);
		    %QuestionDefaults=%QuestionGlobalDefaults;
		}
		my $query = "INSERT INTO Questions 
			     (ParentId, Number) 
			     VALUES ($TourId, $qnum+1)";
		$sth = $dbh->prepare($query);
		$sth->execute or print $query;;
		$QuestionId = $sth->{mysql_insertid};
		&UpdateQuestion($dbh, $QuestionId, "Question", $value);
		while (my ($key,$value)=each %QuestionDefaults) {
		    &UpdateQuestion($dbh, $QuestionId, $key, $value);
		}		
		$qnum++;
		$all_qnum++;
		next;
	    }

	    if ($key =~ /Ответ/) {
		&UpdateQuestion($dbh, $QuestionId, "Answer", $value);
		next;
	    }


	    if ($key =~ /Зач[её]т/) {
		&UpdateQuestion($dbh, $QuestionId, "PassCriteria", $value);
		next;
	    }



	    if ($key =~ /Комментари/) {
		&UpdateQuestion($dbh, $QuestionId, "Comments", $value);
		next;
	    }

	    if ($key =~ /Вид/) { 
		if ($value =~ /^\s*Д\s*$/) {#Questions Д are really ЧД...
		    $value = "ЧД";
		}
		&UpdateQuestion($dbh, $QuestionId, "Type", $value);
		next;
	    }


	    
	    my @Fields = grep { $key =~ /$_/ } keys %QuestionFields;

	    if (scalar @Fields) {
		my $word = shift @Fields;
		my $field = $QuestionFields{$word};
		if ($QuestionId) {
		    &UpdateQuestion($dbh, $QuestionId, $field, $value);
		} elsif ($TourId) {
		    $QuestionDefaults{$field}=$value;
		} else {
		    $QuestionGlobalDefaults{$field}=$value;
		}
		next;
	    }

	    @Fields = grep { $key =~ /$_/ } keys %TourFields;

	    if (scalar @Fields) {
		my $word = shift @Fields;
		my $field = $TourFields{$word};
		if ($QuestionId) {
		    print STDERR "ОШИБКА: $key $value недопустимы после",
		    " начала вопросов\n";
		} elsif ($TourId) {
		    &UpdateTournament($dbh, $TourId, $field, $value);
		} else {
		    &UpdateTournament($dbh, $TournamentId, $field, $value);
		    $TourDefaults{$field}=$value;
		}
		next;
	    }

	    
	    #
	    # If we are here, something got wrong!
	    #
	    print STDERR "\nЯ НЕ ПОНИМАЮ: $key, $value!\n";
	    
	}
	$dbh->do("UPDATE Tournaments SET QuestionsNum=$qnum
			WHERE Id=$TourId");
	$dbh->do("UPDATE Tournaments SET QuestionsNum=$all_qnum
			WHERE Id=$TournamentId");
	&UpdateParents($dbh, $ParentId, $all_qnum,$UnquotedCreated);		
	print STDERR "Всего вопросов: $all_qnum \n";
    }
    close UNSORTED;
    unlink $unsortedname unless $isunsorted;
    $dbh->disconnect;
}
